home *** CD-ROM | disk | FTP | other *** search
/ Shareware Games Galore! / Shareware Games Galore!.iso / arcade / gameser5 / rocket.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1980-01-01  |  2.6 KB  |  82 lines
  1. 0  REM      R O C K E T   L A N D E R 
  2. 1  CLS:KEY OFF
  3. 5  OUT 2,26
  4. 10  P=1
  5. 11  REM ...P  IS THE INPUT PORT NUMBER FOR YOUR KEYBOARD......
  6. 15  REM
  7. 20  REM
  8. 70  PRINT "LUNER LANDING SIMULATIONS"
  9. 80  PRINT "----- ------- -----------"
  10. 100  INPUT "DO YOU WANT INSTRUCTIONS (YES OR NO)";A$
  11. 120  IF LEFT$(A$,1)="N" THEN 390
  12. 160  PRINT
  13. 200  PRINT"YOU ARE LANDING ON THE MOON AND HAVE TAKEN OVER MANUAL"
  14. 210  PRINT"CONTROL 500 FEEF ABOVE A GOOD LANDING SPOT. YOU HAVE A"
  15. 220  PRINT"DOWNWARD VELOCITY OF 50 FT/SEC.   120 UNITS OF FUEL REMAIN."
  16. 225  PRINT
  17. 230  PRINT"HERE ARE THE RULES THAT GOVERN YOUR SPACE VEHICLE:"
  18. 240  PRINT"(1) AFTER EACH SECOND, THE HEIGHT, VELOCITY, AND REMAINING"
  19. 250  PRINT"    FUEL WILL BE REPORTED."
  20. 260  PRINT"(2) AFTER THE REPORT, A'?'WILL BE TYPED.  ENTER THE"
  21. 270  PRINT"    NUMBER OF UNITS OF FUEL YOU WISH TO BURN DURING THE "
  22. 280  PRINT"    NEXT SECOND.  EACH UNIT OF FUEL WILL SLOW YOUR DESCENT"
  23. 290  PRINT"(3) THE MAXIMUM THRUSTOF YOUR ENGINE IS 30 FT/SEC/SEC OR"
  24. 300  PRINT"    30 UNITS OF FUEL PER SECOND"
  25. 310  PRINT"(4) WHEN YOU CONTACT THE LUNAR SURFACE, YOUR DESCENT ENGINE"
  26. 320  PRINT"    WILL AUTOMATICALLY SHUT OFF AND YOU WILL BE GIVEN A"
  27. 330  PRINT"    REPORT OF YOUR LANDING SPEED AND REMAINING FUEL"
  28. 340  PRINT"(5) IF YOU RUN OUT OF FUEL, THE'?' WILL NO LONGER APPEAR"
  29. 350  PRINT"    BUT YOU SECOND BY SECOND REPORT WILL CONTINUE UNTIL"
  30. 360  PRINT"    YOU CONTACT LUNAR SURFACE.":PRINT
  31. 365  PRINT:PRINT"HIT SPACE BAR TO CONTINUE..."
  32. 366  A$=INKEY$:IF A$="" THEN 366
  33. 390  PRINT:PRINT:PRINT"BEGINING LANDING PROCEEDURE.........":PRINT
  34. 410  PRINT"G O O D  L U C K ! ! ! "
  35. 420  PRINT:PRINT
  36. 440  PRINT"SEC   FEET   SPEED   FUEL     PLOT OF DISTANCE"
  37. 450  PRINT
  38. 455  T=0:H=500:V=50:F=120
  39. 490  PRINT T;TAB(4);H;TAB(12);V;TAB(20);F;TAB(29);"I";TAB(H/12+29);"*"
  40. 500  INPUT B
  41. 510  IF B<0 THEN 650
  42. 520  IF B>30 THEN B=30
  43. 530  IF B>F THEN B=F
  44. 540  V1=V-B+5
  45. 560  F=F-B
  46. 570  H=H-0.5*(V+V1)
  47. 580  IF H<=0 THEN 670
  48. 590  T=T+1
  49. 600  V=V1
  50. 610  IF F>0 THEN 490
  51. 615  IF B=0THEN 640
  52. 620  PRINT"***OUT OF FUEL***"
  53. 640  PRINT T;TAB(4);H;TAB(12);V;TAB(20);F;TAB(29);"I";TAB(H/12+29);"*"
  54. 650  B=0
  55. 660  GOTO540
  56. 670  PRINT"****CONTACT****"
  57. 680  H=H+0.5*(V+V1)
  58. 690  IF B=5 THEN 720
  59. 700  D=(-V+SQR(V*V+H*(10-2*B)))/(5-B) 
  60. 710  GOTO 730
  61. 720  D=H/V
  62. 730  V1=V+(5-B)*D
  63. 760  PRINT"   TOUCHDOWN AT";T+D;"SECONDS."
  64. 770  PRINT"   LANDING VELOCITY =";V1;"FT/SEC"
  65. 780  PRINT F;"UNITS OF FUEL REMAINING."
  66. 790  IF V1<>0 THEN 810
  67. 800  PRINT"CONGRADULATIONS!!!     A PERFECT LANDING!"
  68. 805  PRINT"YOUR LICENSE WILL BE RENEWED.........LATER."
  69. 808  GOTO 845
  70. 810  IF ABS(V1)<2 THEN 840
  71. 820  PRINT" *****  SORRY, BUT YOU BLEW IT KIDO!!!!!"
  72. 825  PRINT" THIS WAS OUR ONLY CHANCE TO MAKE CONTACT WITH EXTRATRESTRIAL"
  73. 827  PRINT" BEINGS.  NON-APPROPRIATE CONDOLENCES MIGHT BE SENT TO YOUR"
  74. 830  PRINT" NEXT OF KIN."
  75. 835  GOTO 845
  76. 840  PRINT:PRINT"WELL......THAT WAS OK.  BUT NOT TOO SPECTACULAR..."
  77. 845  PRINT:PRINT
  78. 850  INPUT "ANOTHER MISSION ANYONE";A$
  79. 870  IF LEFT$(A$,1)="Y" THEN 390
  80. 880  PRINT:PRINT  "CONTROL OUT. ":PRINT
  81. 999  END
  82.